# Maintainer: Stephan Eisvogel <eisvogel ät seitics dot de>
# Contributor: Ujhhgtg (https://aur.archlinux.org/account/Ujhhgtg)

_pkgname=icu
_pkgmainver=74
_pkgminorver=2
pkgname="${_pkgname}${_pkgmainver}"
pkgver="${_pkgmainver}.${_pkgminorver}"
pkgrel=6
pkgdesc="International Components for Unicode library (legacy version ${_pkgmainver})."
arch=(x86_64 i686)
url="http://www.icu-project.org/"
license=(LicenseRef-Unicode-3.0 BSD-2-Clause BSD-3-Clause)
depends=(gcc-libs glibc sh)
makedepends=(clang make patch python)
provides=(libicu{data,i18n,io,test,tu,uc}.so=${_pkgmainver})
conflicts=(
  "${_pkgname}=${_pkgmainver}"
  "${_pkgname}=${_pkgmainver}.0"
  "${_pkgname}=${_pkgmainver}.1"
  "${_pkgname}=${_pkgmainver}.2"
  "${_pkgname}=${_pkgmainver}.3"
  "${_pkgname}=${_pkgmainver}.4"
  "${_pkgname}=${_pkgmainver}.5"
  "${_pkgname}=${_pkgmainver}.6"
  "${_pkgname}=${_pkgmainver}.7"
  "${_pkgname}=${_pkgmainver}.8"
  "${_pkgname}=${_pkgmainver}.9"
  "libicudata.so=${_pkgmainver}"
  "libicui18n.so=${_pkgmainver}"
  "libicuio.so=${_pkgmainver}"
  "libicutest.so=${_pkgmainver}"
  "libicutu.so=${_pkgmainver}"
  "libicuuc.so=${_pkgmainver}"
)
source=(
  "https://github.com/unicode-org/icu/releases/download/release-${pkgver//./-}/icu4c-${pkgver//./_}-src.tgz"
  icu74.ld.so.conf
  ICU-22132.patch
  LICENSE
)
sha256sums=(
  '68db082212a96d6f53e35d60f47d38b962e9f9d207a74cfac78029ae8ff5e08c'
  'SKIP'
  'SKIP'
  'SKIP'
)

prepare() {
  cd icu/source
  patch -Np1 < "../../ICU-22132.patch"
}

build()
{
  cd icu/source
  ./configure \
    --prefix=/opt/icu74
  make
}

package()
{
  cd "${_pkgname}/source"
  make DESTDIR="${pkgdir}" install
  install -Dvm644 "${srcdir}/icu74.ld.so.conf" "${pkgdir}/etc/ld.so.conf.d/icu74.conf"
  install -Dvm644 "${srcdir}/LICENSE" "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}