# Maintainer: Stephan Eisvogel <eisvogel at seitics dot de>
# Contributor: Jouni Rinne <l33tmmx swirlything gmail dot com>
# Contributor: Deon Spengler <deon at spengler dot co dot za>
pkgname=labrador
pkgdesc="Qt5 GUI for EspoTek USB oscilloscope, signal generator, PSU, logic analyzer, multimeter"
pkgver=1.0
pkgrel=1
arch=('x86_64')
url="https://espotek.com/labrador/"
license=('GPL3')
depends=('qt5-base' 'hicolor-icon-theme' 'fftw')
makedepends=('git')
source=(
	"git+https://github.com/EspoTek/Labrador"
	"git+https://github.com/EspoTek/libdfuprog"
	"labrador-install.patch"
)
sha256sums=('SKIP' 'SKIP' 'SKIP')

prepare() {
    cd ${srcdir}/libdfuprog
	chmod +x libdfuprog_make_linux

    cd ${srcdir}/Labrador/Desktop_Interface
    patch -p0 -i ../../labrador-install.patch
	sed -i 's/bin\/EspoTek-Labrador\/Labrador/share\/labrador\/Labrador/g' resources/espotek-labrador.desktop
}

build() {
    cd ${srcdir}/libdfuprog
	./bootstrap.sh
	./libdfuprog_make_linux

    cd ${srcdir}/Labrador/Desktop_Interface
    qmake -makefile Labrador.pro
    make
}

package() {
    cd ${srcdir}/Labrador/Desktop_Interface
    make INSTALL_ROOT=${pkgdir} install
	install -D -m 0644 ${srcdir}/libdfuprog/src/libdfuprog-0.9.so ${pkgdir}/usr/lib/libdfuprog-0.9.so
    cp ../{pinout.svg,README.md} ${pkgdir}/usr/share/labrador/
    rm "${pkgdir}/usr/share/labrador/firmware/"{dfu-programmer.exe,flash.bat,wipe.bat}
	mkdir "${pkgdir}/usr/bin"
	chmod 0755 "${pkgdir}/usr/bin"
	ln -s "../share/labrador/Labrador" "${pkgdir}/usr/bin/labrador"
}