# Maintainer: Stephan Eisvogel <eisvogel ät seitics dot de>
pkgname=mft
pkgdesc="Mellanox Firmware Tools"
arch=(x86_64)
url='https://network.nvidia.com/products/adapter-software/firmware-tools/'
license=(custom)
depends=(dkms libxcrypt-compat)
builddepends=(libarchive)
groups=(custom)

pkgrel=1
pkgver=4.18.0
_pkgrel=106
_mft_rpm="mft-$pkgver-$_pkgrel-x86_64-rpm"

source=(
    "https://www.mellanox.com/downloads/MFT/${_mft_rpm}.tgz"
	Makefile
	dkms.conf
	mst_pciconf.patch
)

sha256sums=(
    e267beaf14182c2d76c160db525213a0d320df13416dc41af2f59ef0943ee4ff
	SKIP SKIP SKIP
)

package(){
    # Extract RPMs/SRPMs
    cd "${pkgdir}/"
    _pkgs=$(find "${srcdir}/${_mft_rpm}" -name '*.rpm')
    for _p in ${_pkgs}; do
        echo "Extracting ${_p}"
        bsdtar -xkf "${_p}"
    done

    # Trim and move items
    rm -f mft_kernel.spec usr/bin/{mst,mft_uninstall.sh}
    mv etc/init.d/mst usr/bin
    rm -r etc/mft/RPMS etc/init.d
    mv usr/lib64 usr/lib

    # Install DKMS files
    dkmsdir="${pkgdir}/usr/src/${pkgname}-${pkgver}"
    kernelmft="kernel-mft-${pkgver}"
    tar xzf "${kernelmft}.tgz"
    rm "${kernelmft}.tgz"
    mkdir -p "${dkmsdir}"
	cd "$kernelmft" || exit 1
		patch -Np1 < "${srcdir}/mst_pciconf.patch"
		cp {driver_common,mst_pci,mst_pciconf}.{c,h} "${dkmsdir}"
	cd .. || exit 1
    rm -r "./${kernelmft}"

    cp "${srcdir}/"{Makefile,dkms.conf} "${dkmsdir}"
	sed -e "s/@PKGNAME@/${pkgname}/" \
		-e "s/@PKGVER@/${pkgver}/" \
		-i "${dkmsdir}/dkms.conf"
}